From fbaaef999ba563838ebd00874ed8a1c01fbf286d Mon Sep 17 00:00:00 2001
From: Wink Saville <wink@google.com>
Date: Thu, 27 May 2010 16:25:37 -0700
Subject: Add protobuf 2.2.0a sources

This is the contents of protobuf-2.2.0a.tar.bz2 from
http://code.google.com/p/protobuf/downloads/list and
is the base code for the javamicro code generator.

Change-Id: Ie9a0440a824d615086445b6636944484b3155afa
---
 m4/ac_system_extensions.m4 | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 m4/ac_system_extensions.m4

(limited to 'm4/ac_system_extensions.m4')

diff --git a/m4/ac_system_extensions.m4 b/m4/ac_system_extensions.m4
new file mode 100644
index 0000000..1ca2eeb
--- /dev/null
+++ b/m4/ac_system_extensions.m4
@@ -0,0 +1,37 @@
+dnl Provide AC_USE_SYSTEM_EXTENSIONS for old autoconf machines.
+AC_DEFUN([ACX_USE_SYSTEM_EXTENSIONS],[
+  ifdef([AC_USE_SYSTEM_EXTENSIONS],[
+    AC_USE_SYSTEM_EXTENSIONS
+  ],[
+    AC_BEFORE([$0], [AC_COMPILE_IFELSE])
+    AC_BEFORE([$0], [AC_RUN_IFELSE])
+
+    AC_REQUIRE([AC_GNU_SOURCE])
+    AC_REQUIRE([AC_AIX])
+    AC_REQUIRE([AC_MINIX])
+
+    AH_VERBATIM([__EXTENSIONS__],
+[/* Enable extensions on Solaris.  */
+#ifndef __EXTENSIONS__
+# undef __EXTENSIONS__
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS
+# undef _POSIX_PTHREAD_SEMANTICS
+#endif
+#ifndef _TANDEM_SOURCE
+# undef _TANDEM_SOURCE
+#endif])
+    AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
+      [ac_cv_safe_to_define___extensions__],
+      [AC_COMPILE_IFELSE(
+         [AC_LANG_PROGRAM([
+#           define __EXTENSIONS__ 1
+            AC_INCLUDES_DEFAULT])],
+         [ac_cv_safe_to_define___extensions__=yes],
+         [ac_cv_safe_to_define___extensions__=no])])
+    test $ac_cv_safe_to_define___extensions__ = yes &&
+      AC_DEFINE([__EXTENSIONS__])
+    AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
+    AC_DEFINE([_TANDEM_SOURCE])
+  ])
+])
-- 
cgit v1.1