build: Use AX_PROG_BISON

No one tests yacc/byacc. Let's just request bison specifically.

Tested-by: Andreas Boll <andreas.boll.dev@gmail.com>
Reviewed-by: Eric Anholt <eric@anholt.net>
Bugzilla: https://bugs.freedesktop.org/show_bug.cgi?id=46815

2 files changed, 74 insertions, 7 deletions

diff --git a/configure.ac b/configure.ac
index f338e20..70599e1 100644
--- a/configure.ac
+++ b/configure.ac
@@ -56,13 +56,9 @@ AC_PROG_MKDIR_P
 LT_PREREQ([2.2])
 LT_INIT([disable-static])
 
-AC_PROG_YACC
-AC_PATH_PROG([YACC_INST], $YACC)
-if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
-    if test -z "$YACC_INST"; then
-        AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
-    fi
-fi
+AX_PROG_BISON([],
+              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"]
+                    [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 AC_PROG_LEX
 
 AC_PATH_PROG([PERL], [perl])
diff --git a/m4/ax_prog_bison.m4 b/m4/ax_prog_bison.m4
new file mode 100644
index 0000000..dae4470
--- /dev/null
+++ b/m4/ax_prog_bison.m4
@@ -0,0 +1,71 @@
+# ===========================================================================
+#       http://www.gnu.org/software/autoconf-archive/ax_prog_bison.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PROG_BISON(ACTION-IF-TRUE,ACTION-IF-FALSE)
+#
+# DESCRIPTION
+#
+#   Check whether bison is the parser generator. Run ACTION-IF-TRUE if
+#   successful, ACTION-IF-FALSE otherwise
+#
+# LICENSE
+#
+#   Copyright (c) 2009 Francesco Salvestrini <salvestrini@users.sourceforge.net>
+#   Copyright (c) 2010 Diego Elio Petteno` <flameeyes@gmail.com>
+#
+#   This program is free software; you can redistribute it and/or modify it
+#   under the terms of the GNU General Public License as published by the
+#   Free Software Foundation; either version 2 of the License, or (at your
+#   option) any later version.
+#
+#   This program is distributed in the hope that it will be useful, but
+#   WITHOUT ANY WARRANTY; without even the implied warranty of
+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+#   Public License for more details.
+#
+#   You should have received a copy of the GNU General Public License along
+#   with this program. If not, see <http://www.gnu.org/licenses/>.
+#
+#   As a special exception, the respective Autoconf Macro's copyright owner
+#   gives unlimited permission to copy, distribute and modify the configure
+#   scripts that are the output of Autoconf when processing the Macro. You
+#   need not follow the terms of the GNU General Public License when using
+#   or distributing such scripts, even though portions of the text of the
+#   Macro appear in them. The GNU General Public License (GPL) does govern
+#   all other use of the material that constitutes the Autoconf Macro.
+#
+#   This special exception to the GPL applies to versions of the Autoconf
+#   Macro released by the Autoconf Archive. When you make and distribute a
+#   modified version of the Autoconf Macro, you may extend this special
+#   exception to the GPL to apply to your modified version as well.
+
+#serial 9
+
+# mattst88:
+#     Modified YACC assignment to remove -o y.tab.c since we're writing
+#     our own .y/.yy rules.
+#
+#     Replaced m4_ifnblank(...) with m4_ifval(m4_normalize(...), ...)
+#     since m4_ifnblank requires autoconf-2.64.
+
+AC_DEFUN([AX_PROG_BISON], [
+  AC_REQUIRE([AC_PROG_YACC])
+  AC_REQUIRE([AC_PROG_EGREP])
+
+  AC_CACHE_CHECK([if bison is the parser generator],[ax_cv_prog_bison],[
+    AS_IF([$YACC --version 2>/dev/null | $EGREP -q '^bison '],
+      [ax_cv_prog_bison=yes], [ax_cv_prog_bison=no])
+  ])
+  AS_IF([test "$ax_cv_prog_bison" = "yes"], [
+      dnl replace the yacc-compatible compiler with the real bison, as
+      dnl otherwise autoconf limits us to the POSIX yacc.
+      dnl We also change the generated filename to the old one, so that
+      dnl automake's ylwrap can deal with it.
+      YACC="${YACC% -y}"
+    ] m4_ifval(m4_normalize([$1]), [[$1]]),
+    m4_ifval(m4_normalize([$2]), [[$2]])
+  )
+])