Merge WebKit at r82507: Initial merge by git

Change-Id: I60ce9d780725b58b45e54165733a8ffee23b683e

4 files changed, 326 insertions, 80 deletions

diff --git a/Source/WebKit2/PluginProcess/mac/PluginProcessMac.mm b/Source/WebKit2/PluginProcess/mac/PluginProcessMac.mm
index 5a54719..3a3586a 100644
--- a/Source/WebKit2/PluginProcess/mac/PluginProcessMac.mm
+++ b/Source/WebKit2/PluginProcess/mac/PluginProcessMac.mm
@@ -28,17 +28,98 @@
 
 #if ENABLE(PLUGIN_PROCESS)
 
-// FIXME (WebKit2) <rdar://problem/8728860> WebKit2 needs to be localized
-#define UI_STRING(__str, __desc) [NSString stringWithUTF8String:__str]
-
 #import "NetscapePlugin.h"
 #import "PluginProcessShim.h"
+#import "PluginProcessProxyMessages.h"
 #import "PluginProcessCreationParameters.h"
+#import <WebCore/LocalizedStrings.h>
 #import <WebKitSystemInterface.h>
 #import <dlfcn.h>
+#import <wtf/HashSet.h>
 
 namespace WebKit {
 
+class FullscreenWindowTracker {
+    WTF_MAKE_NONCOPYABLE(FullscreenWindowTracker);
+
+public:
+    FullscreenWindowTracker() { }
+    
+    template<typename T> void windowShown(T window);
+    template<typename T> void windowHidden(T window);
+
+private:
+    typedef HashSet<void*> WindowSet;
+    WindowSet m_windows;
+};
+
+static bool rectCoversAnyScreen(NSRect rect)
+{
+    for (NSScreen *screen in [NSScreen screens]) {
+        if (NSContainsRect(rect, [screen frame]))
+            return YES;
+    }
+    return NO;
+}
+
+#ifndef NP_NO_CARBON
+static bool windowCoversAnyScreen(WindowRef window)
+{
+    HIRect bounds;
+    HIWindowGetBounds(window, kWindowStructureRgn, kHICoordSpaceScreenPixel, &bounds);
+
+    // Convert to Cocoa-style screen coordinates that use a Y offset relative to the zeroth screen's origin.
+    bounds.origin.y = NSHeight([[[NSScreen screens] objectAtIndex:0] frame]) - CGRectGetMaxY(bounds);
+
+    return rectCoversAnyScreen(NSRectFromCGRect(bounds));
+}
+#endif
+
+static bool windowCoversAnyScreen(NSWindow* window)
+{
+    return rectCoversAnyScreen([window frame]);
+}
+
+template<typename T> void FullscreenWindowTracker::windowShown(T window)
+{
+    // If this window is already visible then there is nothing to do.
+    WindowSet::iterator it = m_windows.find(window);
+    if (it != m_windows.end())
+        return;
+    
+    // If the window is not full-screen then we're not interested in it.
+    if (!windowCoversAnyScreen(window))
+        return;
+
+    bool windowSetWasEmpty = m_windows.isEmpty();
+
+    m_windows.add(window);
+    
+    // If this is the first full screen window to be shown, notify the UI process.
+    if (windowSetWasEmpty)
+        PluginProcess::shared().setFullscreenWindowIsShowing(true);
+}
+
+template<typename T> void FullscreenWindowTracker::windowHidden(T window)
+{
+    // If this is not a window that we're tracking then there is nothing to do.
+    WindowSet::iterator it = m_windows.find(window);
+    if (it == m_windows.end())
+        return;
+
+    m_windows.remove(it);
+
+    // If this was the last full screen window that was visible, notify the UI process.
+    if (m_windows.isEmpty())
+        PluginProcess::shared().setFullscreenWindowIsShowing(false);
+}
+
+static FullscreenWindowTracker& fullscreenWindowTracker()
+{
+    DEFINE_STATIC_LOCAL(FullscreenWindowTracker, fullscreenWindowTracker, ());
+    return fullscreenWindowTracker;
+}
+
 static bool isUserbreakSet = false;
 
 static void initShouldCallRealDebugger()
@@ -78,18 +159,62 @@ static UInt32 getCurrentEventButtonState()
 #endif
 }
     
+static void cocoaWindowShown(NSWindow *window)
+{
+    fullscreenWindowTracker().windowShown(window);
+}
+
+static void cocoaWindowHidden(NSWindow *window)
+{
+    fullscreenWindowTracker().windowHidden(window);
+}
+
+static void carbonWindowShown(WindowRef window)
+{
+#ifndef NP_NO_CARBON
+    fullscreenWindowTracker().windowShown(window);
+#endif
+}
+
+static void carbonWindowHidden(WindowRef window)
+{
+#ifndef NP_NO_CARBON
+    fullscreenWindowTracker().windowHidden(window);
+#endif
+}
+
+static void setModal(bool modalWindowIsShowing)
+{
+    PluginProcess::shared().setModalWindowIsShowing(modalWindowIsShowing);
+}
+
 void PluginProcess::initializeShim()
 {
     const PluginProcessShimCallbacks callbacks = {
         shouldCallRealDebugger,
         isWindowActive,
-        getCurrentEventButtonState
+        getCurrentEventButtonState,
+        cocoaWindowShown,
+        cocoaWindowHidden,
+        carbonWindowShown,
+        carbonWindowHidden,
+        setModal,
     };
 
     PluginProcessShimInitializeFunc initFunc = reinterpret_cast<PluginProcessShimInitializeFunc>(dlsym(RTLD_DEFAULT, "WebKitPluginProcessShimInitialize"));
     initFunc(callbacks);
 }
 
+void PluginProcess::setModalWindowIsShowing(bool modalWindowIsShowing)
+{
+    m_connection->send(Messages::PluginProcessProxy::SetModalWindowIsShowing(modalWindowIsShowing), 0);
+}
+
+void PluginProcess::setFullscreenWindowIsShowing(bool fullscreenWindowIsShowing)
+{
+    m_connection->send(Messages::PluginProcessProxy::SetFullscreenWindowIsShowing(fullscreenWindowIsShowing), 0);
+}
+
 void PluginProcess::platformInitialize(const PluginProcessCreationParameters& parameters)
 {
     m_compositingRenderServerPort = parameters.acceleratedCompositingPort.port();
diff --git a/Source/WebKit2/PluginProcess/mac/PluginProcessShim.cpp b/Source/WebKit2/PluginProcess/mac/PluginProcessShim.cpp
deleted file mode 100644
index 346ead9..0000000
--- a/Source/WebKit2/PluginProcess/mac/PluginProcessShim.cpp
+++ /dev/null
@@ -1,76 +0,0 @@
-/*
- * Copyright (C) 2010 Apple Inc. All rights reserved.
- *
- * Redistribution and use in source and binary forms, with or without
- * modification, are permitted provided that the following conditions
- * are met:
- * 1. Redistributions of source code must retain the above copyright
- *    notice, this list of conditions and the following disclaimer.
- * 2. Redistributions in binary form must reproduce the above copyright
- *    notice, this list of conditions and the following disclaimer in the
- *    documentation and/or other materials provided with the distribution.
- *
- * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
- * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
- * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
- * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
- * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
- * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
- * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
- * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
- * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
- * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
- * THE POSSIBILITY OF SUCH DAMAGE.
- */
-
-#include "PluginProcessShim.h"
-
-#include <Carbon/Carbon.h>
-#include <stdio.h>
-
-#define DYLD_INTERPOSE(_replacement,_replacee) \
-    __attribute__((used)) static struct{ const void* replacement; const void* replacee; } _interpose_##_replacee \
-    __attribute__ ((section ("__DATA,__interpose"))) = { (const void*)(unsigned long)&_replacement, (const void*)(unsigned long)&_replacee };
-
-namespace WebKit {
-
-extern "C" void WebKitPluginProcessShimInitialize(const PluginProcessShimCallbacks& callbacks);
-
-PluginProcessShimCallbacks pluginProcessShimCallbacks;
-
-__attribute__((visibility("default")))
-void WebKitPluginProcessShimInitialize(const PluginProcessShimCallbacks& callbacks)
-{
-    pluginProcessShimCallbacks = callbacks;
-}
-
-#ifndef __LP64__
-static void shimDebugger(void)
-{
-    if (!pluginProcessShimCallbacks.shouldCallRealDebugger())
-        return;
-    
-    Debugger();
-}
-
-static UInt32 shimGetCurrentEventButtonState()
-{
-    return pluginProcessShimCallbacks.getCurrentEventButtonState();
-}
-
-static Boolean shimIsWindowActive(WindowRef window)
-{
-    bool result;
-    if (pluginProcessShimCallbacks.isWindowActive(window, result))
-        return result;
-    
-    return IsWindowActive(window);
-}
-
-DYLD_INTERPOSE(shimDebugger, Debugger);
-DYLD_INTERPOSE(shimGetCurrentEventButtonState, GetCurrentEventButtonState);
-DYLD_INTERPOSE(shimIsWindowActive, IsWindowActive);
-    
-#endif
-
-} // namespace WebKit
diff --git a/Source/WebKit2/PluginProcess/mac/PluginProcessShim.h b/Source/WebKit2/PluginProcess/mac/PluginProcessShim.h
index 0fbee23..b021a3a 100644
--- a/Source/WebKit2/PluginProcess/mac/PluginProcessShim.h
+++ b/Source/WebKit2/PluginProcess/mac/PluginProcessShim.h
@@ -26,6 +26,8 @@
 #ifndef PluginProcessShim_h
 #define PluginProcessShim_h
 
+@class NSWindow;
+
 #include <Carbon/Carbon.h>
 
 namespace WebKit {
@@ -34,6 +36,11 @@ struct PluginProcessShimCallbacks {
     bool (*shouldCallRealDebugger)();
     bool (*isWindowActive)(WindowRef, bool& result);
     UInt32 (*getCurrentEventButtonState)();
+    void (*cocoaWindowShown)(NSWindow *);
+    void (*cocoaWindowHidden)(NSWindow *);
+    void (*carbonWindowShown)(WindowRef);
+    void (*carbonWindowHidden)(WindowRef);
+    void (*setModal)(bool);
 };
 
 typedef void (*PluginProcessShimInitializeFunc)(const PluginProcessShimCallbacks&);
diff --git a/Source/WebKit2/PluginProcess/mac/PluginProcessShim.mm b/Source/WebKit2/PluginProcess/mac/PluginProcessShim.mm
new file mode 100644
index 0000000..6a32727
--- /dev/null
+++ b/Source/WebKit2/PluginProcess/mac/PluginProcessShim.mm
@@ -0,0 +1,190 @@
+/*
+ * Copyright (C) 2010 Apple Inc. All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
+ * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+ * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+ * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
+ * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+ * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+ * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+ * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+ * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
+ * THE POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#import "PluginProcessShim.h"
+
+#import <AppKit/AppKit.h>
+#import <Carbon/Carbon.h>
+#import <WebKitSystemInterface.h>
+#import <stdio.h>
+#import <objc/objc-runtime.h>
+
+#define DYLD_INTERPOSE(_replacement,_replacee) \
+    __attribute__((used)) static struct{ const void* replacement; const void* replacee; } _interpose_##_replacee \
+    __attribute__ ((section ("__DATA,__interpose"))) = { (const void*)(unsigned long)&_replacement, (const void*)(unsigned long)&_replacee };
+
+namespace WebKit {
+
+extern "C" void WebKitPluginProcessShimInitialize(const PluginProcessShimCallbacks& callbacks);
+
+static PluginProcessShimCallbacks pluginProcessShimCallbacks;
+
+static IMP NSApplication_RunModalForWindow;
+static unsigned modalCount = 0;
+
+static void beginModal()
+{
+    // Make sure to make ourselves the front process
+    ProcessSerialNumber psn;
+    GetCurrentProcess(&psn);
+    SetFrontProcess(&psn);
+    
+    if (!modalCount++)
+        pluginProcessShimCallbacks.setModal(true);
+}
+
+static void endModal()
+{
+    if (!--modalCount)
+        pluginProcessShimCallbacks.setModal(false);
+}    
+
+static NSInteger shim_NSApplication_RunModalForWindow(id self, SEL _cmd, NSWindow* window)
+{
+    beginModal();
+    NSInteger result = ((NSInteger (*)(id, SEL, NSWindow *))NSApplication_RunModalForWindow)(self, _cmd, window);
+    endModal();
+
+    return result;
+}
+
+#ifndef __LP64__
+static void shimDebugger(void)
+{
+    if (!pluginProcessShimCallbacks.shouldCallRealDebugger())
+        return;
+    
+    Debugger();
+}
+
+static UInt32 shimGetCurrentEventButtonState()
+{
+    return pluginProcessShimCallbacks.getCurrentEventButtonState();
+}
+
+static Boolean shimIsWindowActive(WindowRef window)
+{
+    bool result;
+    if (pluginProcessShimCallbacks.isWindowActive(window, result))
+        return result;
+    
+    return IsWindowActive(window);
+}
+
+static void shimModalDialog(ModalFilterUPP modalFilter, DialogItemIndex *itemHit)
+{
+    beginModal();
+    ModalDialog(modalFilter, itemHit);
+    endModal();
+}
+
+static DialogItemIndex shimAlert(SInt16 alertID, ModalFilterUPP modalFilter)
+{
+    beginModal();
+    DialogItemIndex index = Alert(alertID, modalFilter);
+    endModal();
+    
+    return index;
+}
+
+static void shimShowWindow(WindowRef window)
+{
+    pluginProcessShimCallbacks.carbonWindowShown(window);
+    ShowWindow(window);
+}
+
+static void shimHideWindow(WindowRef window)
+{
+    pluginProcessShimCallbacks.carbonWindowHidden(window);
+    HideWindow(window);
+}
+
+static bool isMenuBarVisible = true;
+
+static void shimShowMenuBar(void)
+{
+    isMenuBarVisible = true;
+
+    ShowMenuBar();
+}
+
+static void shimHideMenuBar(void)
+{
+    isMenuBarVisible = false;
+
+    // Make sure to make ourselves the front process
+    ProcessSerialNumber psn;
+    GetCurrentProcess(&psn);
+    SetFrontProcess(&psn);
+    
+    HideMenuBar();
+}
+
+static Boolean shimIsMenuBarVisible(void)
+{
+    return isMenuBarVisible;
+}
+
+DYLD_INTERPOSE(shimDebugger, Debugger);
+DYLD_INTERPOSE(shimGetCurrentEventButtonState, GetCurrentEventButtonState);
+DYLD_INTERPOSE(shimIsWindowActive, IsWindowActive);
+DYLD_INTERPOSE(shimModalDialog, ModalDialog);
+DYLD_INTERPOSE(shimAlert, Alert);
+DYLD_INTERPOSE(shimShowWindow, ShowWindow);
+DYLD_INTERPOSE(shimHideWindow, HideWindow);
+DYLD_INTERPOSE(shimShowMenuBar, ShowMenuBar)
+DYLD_INTERPOSE(shimHideMenuBar, HideMenuBar)
+DYLD_INTERPOSE(shimIsMenuBarVisible, IsMenuBarVisible);
+
+#endif
+
+__attribute__((visibility("default")))
+void WebKitPluginProcessShimInitialize(const PluginProcessShimCallbacks& callbacks)
+{
+    pluginProcessShimCallbacks = callbacks;
+
+    // Override -[NSApplication runModalForWindow:]
+    Method runModalForWindowMethod = class_getInstanceMethod(objc_getClass("NSApplication"), @selector(runModalForWindow:));
+    NSApplication_RunModalForWindow = method_setImplementation(runModalForWindowMethod, reinterpret_cast<IMP>(shim_NSApplication_RunModalForWindow));
+
+    NSNotificationCenter *defaultCenter = [NSNotificationCenter defaultCenter];
+
+    // Track when any Cocoa window is about to be be shown.
+    id orderOnScreenObserver = [defaultCenter addObserverForName:WKWindowWillOrderOnScreenNotification()
+                                                          object:nil
+                                                           queue:nil
+                                                           usingBlock:^(NSNotification *notification) { pluginProcessShimCallbacks.cocoaWindowShown([notification object]); }];
+    // Track when any cocoa window is about to be hidden.
+    id orderOffScreenObserver = [defaultCenter addObserverForName:WKWindowWillOrderOffScreenNotification()
+                                                           object:nil
+                                                            queue:nil
+                                                       usingBlock:^(NSNotification *notification) { pluginProcessShimCallbacks.cocoaWindowHidden([notification object]); }];
+
+    // Leak the two observers so that they observe notifications for the lifetime of the process.
+    CFRetain(orderOnScreenObserver);
+    CFRetain(orderOffScreenObserver);
+}
+
+} // namespace WebKit