blob: e4075a45d75af905f4a40301ff1c62f5f7d9bd88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
@echo off
set PublicHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\JavaScriptCore
set PrivateHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\private\JavaScriptCore
set ResourcesDirectory=%CONFIGURATIONBUILDDIR%\bin\JavaScriptCore.resources
if "%1" EQU "clean" goto :clean
if "%1" EQU "rebuild" call :clean
echo Copying public headers...
mkdir "%PublicHeadersDirectory%" 2>NUL
for %%f in (
APICast.h
APIShims.h
JSBase.h
JSContextRef.h
JSContextRefPrivate.h
JSObjectRef.h
JSObjectRefPrivate.h
JSRetainPtr.h
JSRetainPtr.h
JSStringRef.h
JSStringRefBSTR.h
JSStringRefCF.h
JSValueRef.h
JSWeakObjectMapRefInternal.h
JSWeakObjectMapRefPrivate.h
JavaScript.h
JavaScriptCore.h
OpaqueJSString.h
WebKitAvailability.h
) do (
xcopy /y /d ..\..\API\%%f "%PublicHeadersDirectory%" >NUL
)
echo Copying private headers...
mkdir "%PrivateHeadersDirectory%" 2>NUL
for %%d in (
assembler
bytecode
heap
debugger
interpreter
jit
parser
profiler
runtime
wtf
wtf\text
wtf\unicode
wtf\unicode\icu
yarr
) do (
xcopy /y /d ..\..\%%d\*.h "%PrivateHeadersDirectory%" >NUL
)
echo Copying resources...
mkdir "%ResourcesDirectory%" 2>NUL
xcopy /y /d ..\JavaScriptCore.resources\* "%ResourcesDirectory%" >NUL
echo Copying other files...
for %%f in (
create_hash_table
wtf\text\AtomicString.cpp
wtf\text\StringBuilder.cpp
wtf\text\StringImpl.cpp
wtf\text\WTFString.cpp
) do (
xcopy /y /d ..\..\%%f "%PrivateHeadersDirectory%" >NUL
)
goto :EOF
:clean
echo Deleting copied files...
if exist "%PublicHeadersDirectory%" rmdir /s /q "%PublicHeadersDirectory%" >NUL
if exist "%PrivateHeadersDirectory%" rmdir /s /q "%PrivateHeadersDirectory%" >NUL
if exist "%ResourcesDirectory%" rmdir /s /q "%ResourcesDirectory%" >NUL
|