WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

TEMPLATE = lib
TARGET = TestNetscapePlugIn

VPATH = ../../gtk/TestNetscapePlugin ../../TestNetscapePlugIn.subproj
include(../../../../WebKit.pri)

DESTDIR = $$OUTPUT_DIR/lib/plugins

mac {
    CONFIG += plugin
    CONFIG += plugin_bundle
    QMAKE_INFO_PLIST = ../../TestNetscapePlugIn.subproj/Info.plist
    QMAKE_PLUGIN_BUNDLE_NAME = $$TARGET
    QMAKE_BUNDLE_LOCATION += "Contents/MacOS"

    !build_pass:CONFIG += build_all
    debug_and_release:TARGET = $$qtLibraryTarget($$TARGET)
}

INCLUDEPATH += ../../../../JavaScriptCore \
               ../../gtk/TestNetscapePlugin/ForwardingHeaders \
               ../../gtk/TestNetscapePlugin/ForwardingHeaders/WebKit \
               ../../../../WebCore \
               ../../../../WebCore/bridge \
               ../../TestNetscapePlugIn.subproj

SOURCES = PluginObject.cpp \
          TestObject.cpp

mac {
    SOURCES += ../../TestNetscapePlugIn.subproj/main.cpp
    LIBS += -framework Carbon
} else {
    SOURCES += ../../gtk/TestNetscapePlugin/TestNetscapePlugin.cpp
}