Update maven artifacts and add lint.

Updated the groupId of most artifacts to be more
reflective of their sub-projects status in the SDK tools.

Added lint artifacts.

Change-Id: I900a165647a9b7d3c55b473f63c4ca4469762d7b

1 files changed, 85 insertions, 0 deletions

diff --git a/lint/cli/build.gradle b/lint/cli/build.gradle
new file mode 100644
index 0000000..7cd02dc
--- /dev/null
+++ b/lint/cli/build.gradle
@@ -0,0 +1,85 @@
+dependencies {
+    compile project(':lint_api')
+    compile project(':lint_checks')
+
+    testCompile 'org.easymock:easymock:3.1'
+    testCompile 'junit:junit:3.8.1'
+}
+
+def getVersion() {
+    if (project.has("release")) {
+        return project.ext.baseVersion
+    }
+
+    return project.ext.baseVersion + '-SNAPSHOT'
+}
+
+version = getVersion()
+group = 'com.android.tools.lint'
+archivesBaseName = 'lint'
+
+sourceSets {
+    main {
+        java {
+            srcDir 'src'
+        }
+        resources {
+            srcDir 'src'
+        }
+    }
+    test {
+        java {
+            srcDir 'tests/src'
+        }
+        resources {
+            srcDir 'tests/src'
+        }
+    }
+}
+
+jar {
+    manifest { attributes 'Main-Class': 'com.android.tools.lint.Main' }
+}
+
+uploadArchives {
+    repositories {
+        mavenDeployer {
+            beforeDeployment { MavenDeployment deployment ->
+                if (!project.has("release")) {
+                    throw new StopExecutionException("uploadArchives must be called with the release.gradle init script")
+                }
+
+                signing.signPom(deployment)
+            }
+
+            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
+                authentication(userName: sonatypeUsername, password: sonatypePassword)
+            }
+
+            pom.project {
+                name 'Android Lint Tool'
+                description 'Lint tools. Both a Command line tool and a library to add lint features to other tools'
+                url 'http://tools.android.com'
+                inceptionYear '2007'
+
+                licenses {
+                    license {
+                        name 'The Apache Software License, Version 2.0'
+                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                        distribution 'repo'
+                    }
+                }
+
+                scm {
+                    url "https://android.googlesource.com/platform/sdk"
+                    connection "git://android.googlesource.com/platform/sdk.git"
+                }
+                developers {
+                    developer {
+                        name 'The Android Open Source Project'
+                    }
+                }
+            }
+        }
+    }
+}