Update maven artifacts and add lint.

Updated the groupId of most artifacts to be more
reflective of their sub-projects status in the SDK tools.

Added lint artifacts.

Change-Id: I900a165647a9b7d3c55b473f63c4ca4469762d7b

1 files changed, 76 insertions, 0 deletions

diff --git a/lint/libs/lint_api/build.gradle b/lint/libs/lint_api/build.gradle
new file mode 100644
index 0000000..315c2bb
--- /dev/null
+++ b/lint/libs/lint_api/build.gradle
@@ -0,0 +1,76 @@
+dependencies {
+    compile project(':common')
+    compile project(':sdklib')
+    compile project(':layoutlib_api')
+
+    compile 'com.google.guava:guava:13.0.1'
+    compile 'org.projectlombok:lombok.ast:0.2'
+    compile 'org.ow2.asm:asm:4.0'
+    compile 'org.ow2.asm:asm-tree:4.0'
+}
+
+def getVersion() {
+    if (project.has("release")) {
+        return project.ext.baseVersion
+    }
+
+    return project.ext.baseVersion + '-SNAPSHOT'
+}
+
+version = getVersion()
+group = 'com.android.tools.lint'
+archivesBaseName = 'lint-api'
+
+sourceSets {
+    main {
+        java {
+            srcDir 'src'
+        }
+        resources {
+            srcDir 'src'
+        }
+    }
+}
+
+uploadArchives {
+    repositories {
+        mavenDeployer {
+            beforeDeployment { MavenDeployment deployment ->
+                if (!project.has("release")) {
+                    throw new StopExecutionException("uploadArchives must be called with the release.gradle init script")
+                }
+
+                signing.signPom(deployment)
+            }
+
+            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
+                authentication(userName: sonatypeUsername, password: sonatypePassword)
+            }
+
+            pom.project {
+                name 'Android Tools Lint API'
+                description 'API to build lint checks'
+                url 'http://tools.android.com'
+                inceptionYear '2007'
+
+                licenses {
+                    license {
+                        name 'The Apache Software License, Version 2.0'
+                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                        distribution 'repo'
+                    }
+                }
+
+                scm {
+                    url "https://android.googlesource.com/platform/sdk"
+                    connection "git://android.googlesource.com/platform/sdk.git"
+                }
+                developers {
+                    developer {
+                        name 'The Android Open Source Project'
+                    }
+                }
+            }
+        }
+    }
+}